Đến nội dung


Hình ảnh
- - - - -

Nhờ viết lisp tính diện tích ...


  • Please log in to reply
13 replies to this topic

#1 sonhaxatac

sonhaxatac

    biết pan

  • Members
  • Pip
  • 8 Bài viết
Điểm đánh giá: 0 (bình thường)

Đã gửi 11 June 2014 - 10:50 PM

Nhờ các bác viết hộ e cái lisp mà khi tính diện tích xong rồi mình pick vào text(text có giá trị là số)  để ghi giá trị thì nó sẽ lấy giá trị của text đó để trừ đi giá trị của diện tích vừa tính được và ghi mới vào text đó.

cảm ơn các bác nhiều


  • 0

#2 phamthanhbinh

phamthanhbinh

    biết lệnh adcenter

  • Moderator
  • PipPipPipPipPipPipPip
  • 6007 Bài viết
Điểm đánh giá: 3113 (tuyệt vời)

Đã gửi 12 June 2014 - 10:54 AM

Nhờ các bác viết hộ e cái lisp mà khi tính diện tích xong rồi mình pick vào text(text có giá trị là số)  để ghi giá trị thì nó sẽ lấy giá trị của text đó để trừ đi giá trị của diện tích vừa tính được và ghi mới vào text đó.

cảm ơn các bác nhiều

Hề hề hề,

Thư gửi bạn Sonhaxa...... tắc.

Yêu cầu viết lisp kiểu này thì chả những Sonhaxa ...... tắc mà có nhẽ nhiều người khác cũng ..... tắc thôi.

Hãy đọc kỹ quy định của diễn đàn về việc post các yêu cầu về lisp, đồng thời thực hiện đúng như vậy thì may ra Sonhaxa mới có thể hết tắc. Bằng không thì sẽ còn tắc dài dài vậy.


  • 0
Chúc các quý Anh trên diễn đàn luôn khỏe, đẻ thêm được nhiều thứ để mót.

#3 sonhaxatac

sonhaxatac

    biết pan

  • Members
  • Pip
  • 8 Bài viết
Điểm đánh giá: 0 (bình thường)

Đã gửi 12 June 2014 - 03:06 PM

Hề hề hề,

Thư gửi bạn Sonhaxa...... tắc.

Yêu cầu viết lisp kiểu này thì chả những Sonhaxa ...... tắc mà có nhẽ nhiều người khác cũng ..... tắc thôi.

Hãy đọc kỹ quy định của diễn đàn về việc post các yêu cầu về lisp, đồng thời thực hiện đúng như vậy thì may ra Sonhaxa mới có thể hết tắc. Bằng không thì sẽ còn tắc dài dài vậy.

bác cho e xin link quy định với, tìm mãi mà không thấy đâu


  • 0

#4 TayNgang09

TayNgang09

    Chưa sử dụng CAD

  • Members
  • Pip
  • 2 Bài viết
Điểm đánh giá: 1 (bình thường)

Đã gửi 12 June 2014 - 10:29 PM

Bạn dùng thử lisp này
(defun C:Dti (/ LwuBien mien TFan KhuVwc Bien Dien Mau GocGach DTich Tong Vitri TxtDTiCu TenFile TenTamj FileDTI)
    (setq LwuBien (list (getvar "cmdecho")
                                            (getvar "osmode")
                                            (getvar "CLAYER")
                                            (getvar "pdmode")
                                            (getvar "pdsize")
                                            (getvar "BLIPMODE")
                                            (getvar "angbase")
                                            (getvar "angdir")
                                            (getvar "orthomode")

                                            ))
    (if    (/= (substr (getvar "modemacro") 1 2)  "TD")
            (alert "KHÔNG NÊN DÙNG PHÍM ESCAPE TRONG KHI TH\U+1EF0C HI\U+1EC6N CÁC LÊNH H\U+1ED6 TR\U+1EE2 NÀY"))
    (setvar "modemacro" "TD40")
    (if    (not (tblsearch "Style" "TDKieu"))
        (COMMAND "-Style" "TDKieu" "txt.shx" 1 1 0 "N" "N" ""))
    (if (tblsearch "layer" "TDLddong")
        (command "-layer" "off" "TDlddong" "")
    )
    (setq    Tong 0 DTich 0    )
    (setvar "osmode" 0)
    (setvar "cmdecho" 0)
    (setvar "orthomode" 0)
    (setq DTuongTamj (ssadd))
    (setq TFan 4)
    (setq GocGach 270)
    (setq mien T)
    (While mien
        (setq    mien (getpoint "\nCh\U+1ECDn \U+0111i\U+1EC3m trong khu v\U+1EF1c c\U+1EA7n tính di\U+1EC7n tích: "))
        (command ".BOUNDARY" "a" "o" "r" "i" "n" "+X" "" mien "")
        (setq bien (entlast))
        (ssadd bien DTuongTamj)
        (setq DgBao (cdr (assoc 0 (entget bien))))
        (if    (or (= DgBao "REGION") (= DgBao "LWPOLYLINE"))
            (progn
                (command "Area" "o" bien )
                (setq DTich (getvar "area")
                            Tong (+ Tong DTich))
                (redraw bien 3)
                (command "-hatch" "p" "ANSI31" ( / (getvar "VIEWSIZE") 20 ) (setq GocGach (+ GocGach 30)) mien "")
                (ssadd (entlast) DTuongTamj)
                (redraw bien 3)
                (setq    mien
                     (getpoint
                         (Strcat
                             "\nK\U+1EBFt qu\U+1EA3 "
                             "\nKhu v\U+1EF1c nét \U+0111\U+1EE9t có di\U+1EC7n tích : "
                             (Rtos DTich 2 4)
                             "  \nT\U+1ED5ng di\U+1EC7n tích \U+0111ã tính : "
                             (Rtos Tong 2 4)
                             "\nCh\U+1ECDn \U+0111i\U+1EC3m trong khu v\U+1EF1c \U+0111\U+1EC3 tính ti\U+1EBFp di\U+1EC7n tích. \U+1EA4n <ENTER> \U+0111\U+1EC3 thôi tính: "
                         )
                     )
                )
                (redraw bien 4)
            )
            (progn
                (alert (strcat "Khu v\U+1EF1c \U+0111\U+01B0\U+1EE3c chon không kín ho\U+1EB7c không th\U+1EC3 hi\U+1EC7n h\U+1EBFt trên màn hình."
                                             " Ch\U+1ECDn \U+0111i\U+1EC3m khác \U+0111\U+1EC3 tính ti\U+1EBFp di\U+1EC7n tích"))
                (setq mien T)
            )
        )
    )
    (initget "Chon" 1)
    (setq Vitri (entsel (strcat "\nCh\U+1ECDn \U+0111\U+1ED1i t\U+01B0\U+1EE3ng TEXT \U+0111\U+1EC3 ghi chèn giá tr\U+1ECB di\U+1EC7n tích v\U+1EEBa "
                                                                        "tính [ Ch\U+1ECDn v\U+1ECB trí m\U+1EDBi ]: < Không ghi > ")))
    (while Vitri
        (cond
         ((= Vitri "Chon")
            (setq Vitri (getpoint "\nCh\U+1ECDn v\U+1ECB trí \U+0111\U+1EC3 ghi k\U+1EBFt qu\U+1EA3 : < Không ghi >"))
            (if Vitri (command "text" "j" "mc" Vitri "" (Rtos Tong 2 2)))
            (setq Vitri nil TenFile T)
         )
         ((= (cdr (assoc 0 (entget (car Vitri)))) "TEXT")
            (entmod (subst (cons 1 (Rtos Tong 2 2)) (assoc 1 (entget (car Vitri))) (entget (car Vitri))))
            (setq Vitri nil TenFile T)
         )
         (T
            (alert "Không ghi \U+0111\U+01B0\U+1EE3c k\U+1EBFt qu\U+1EA3 lên \U+0111\U+1ED1i t\U+01B0\U+1EE3ng \U+0111ã ch\U+1ECDn ")
            (setq Vitri (entsel (strcat "\nCh\U+1ECDn l\U+1EA1i \U+0111\U+1ED1i t\U+01B0\U+1EE3ng TEXT \U+0111\U+1EC3 ghi chèn giá tr\U+1ECB "
                                                                        "di\U+1EC7n tích v\U+1EEBa tính [ Ch\U+1ECDn v\U+1ECB trí m\U+1EDBi ]: < Không ghi > ")))
         )
        )
    )
    (if (tblsearch "layer" "TDLddong")
        (command "-layer" "on" "TDlddong" "")
    )

    (if TenFile
        (progn
            (setq TenFile (strcat (getvar "dwgPREFIX") (substr (getvar "dwgname") 1 (- (strlen (getvar "dwgname")) 4)) ".dti"))
            (if (not (findfile TenFile))
                (progn
                    (alert (strcat "K\U+1EBFt qu\U+1EA3 tính di\U+1EC7n tích s\U+1EBD \U+0111\U+01B0\U+1EE3c ghi vào file " TenFile))
                )
            )
            (setq TenMC (entsel "\nCh\U+1ECDn TEXT \U+0111\U+1EC3 l\U+1EA5y tên m\U+1EB7t c\U+1EAFt v\U+1EEBa tính: <Nh\U+1EADp tên> "))
            
            (if TenMC
                (setq TenMC (cdr (assoc 1 (entget (car TenMC)))))
                (setq TenMC (getstring "\nTên m\U+1EB7t c\U+1EAFt v\U+1EEBa tính di\U+1EC7n tích : "))
            )
            (if (= TenMC "") (setq TenMC "KHÔNG TÊN"))
            (setq    FileDTI (open TenFile "a"))
            (write-line (strcat TenMC "\t" (Rtos Tong 2 4)) FileDTI)
            (close FileDTI)
            (print (strcat " M\U+1EB7t c\U+1EAFt " TenMC " có di\U+1EC7n tích " (Rtos Tong 2 4) " \U+0111ã \U+0111\U+01B0\U+1EE3c ghi "))
        )
    )
    (command ".erase" DTuongTamj "")
    (command "regen")
    (princ)
    (setvar "cmdecho"     (nth 0 LwuBien))
    (setvar "osmode"         (nth 1 LwuBien))
    (setvar "CLAYER"         (nth 2 LwuBien))
    (setvar "pdmode"         (nth 3 LwuBien))
    (setvar "pdsize"         (nth 4 LwuBien))
    (setvar "BLIPMODE"     (nth 5 LwuBien))
    (setvar "angbase"     (nth 6 LwuBien))
    (setvar "angdir"         (nth 7 LwuBien))
    (setvar "orthomode" (nth 8 LwuBien))
    (princ)
)
  • 1

#5 sonhaxatac

sonhaxatac

    biết pan

  • Members
  • Pip
  • 8 Bài viết
Điểm đánh giá: 0 (bình thường)

Đã gửi 12 June 2014 - 10:55 PM

Bạn dùng thử lisp này
 

cảm ơn bác nhưng hình như bác hiểu sai ý e, ý e là khi tính diện tích xong mình pick vào text thì nó sẽ lấy giá trị có sẵn của text đó trừ đi diện tích vừa tính được rồi mới ghi kết quả ra


  • 0

#6 Doan Van Ha

Doan Van Ha

    biết lệnh adcenter

  • CADViet Team
  • PipPipPipPipPipPipPip
  • 5447 Bài viết
Điểm đánh giá: 2624 (tuyệt vời)

Đã gửi 13 June 2014 - 06:27 AM

Đây!

(defun C:HA( / ent1 ent2 dt1 dt2 obj2)
 (while
  (and
   (setq ent1 (car (entsel "\nChon doi tuong can tinh dien tich: ")))
   (setq ent2 (car (entsel "\nChon text can hieu chinh gia tri: "))))
  (setq dt1 (vla-get-Area (vlax-ename->vla-object ent1)))
  (setq dt2 (atof (vla-get-textstring (setq obj2 (vlax-ename->vla-object ent2)))))
  (vla-put-textstring obj2 (rtos (- dt2 dt1) 2))))
 


  • 1

* Chỉ nên yêu cầu Lisp khi bạn làm việc đó mất cả ngày nhưng họ chỉ viết 1 giờ. Đừng nêu yêu cầu Lisp khi bạn chỉ làm 1 giờ nhưng bắt họ phải mất cả ngày.

* Nhờ viết lisp cũng như đi khám bệnh. Chỉ gởi căn cước và than sắp chết thì không bác sỹ nào cứu sống được.


#7 sonhaxatac

sonhaxatac

    biết pan

  • Members
  • Pip
  • 8 Bài viết
Điểm đánh giá: 0 (bình thường)

Đã gửi 13 June 2014 - 01:48 PM

Đây!

thank bác nhưng bác sửa cho e phần tính diện tích bằng cách pick vào vùng cần tính diện tích như lisp này được không ạ, phần tính diện tích của bác chỉ tính diện tích được 1 vùng, không linh hoạt lắm 

(defun c:N()
  (if (= tl nil) (progn
    (setq tl (getreal "\nDrawing scale : "))
    (setq ntl (/ 100 tl))
    (setq tl2 (* ntl ntl))
    )
  )
  (setq dtl 0)
  (setq ss (ssadd))
  (setq oslast (getvar "OSMODE"))
  (command "osnap" "")
  (print)
  (print)
  (setq pt1 (getpoint "\nPick internal point : "))
  (while (/= pt1 nil)
    (command "-boundary" pt1 "")
    (setq et (entlast))
    (ssadd et ss)
    (command "area" "e" "last")
    (setq vsize ( /(getvar "VIEWSIZE") 3 ))
    (command "hatch" "ANSI31" vsize "0" "last" "")
    (setq et (entlast))
    (ssadd et ss)
    (setq dtcon (getvar "AREA"))
    (setq dtl (+ dtcon dtl))
    (print)
    (print)
    (setq pt1 (getpoint "\nPick internal point : "))
  )
  (command "setvar" "OSMODE" oslast)
  (command "erase" ss "")
  (setq ss nil)
  (command "redraw")
  (setq dtl (/ dtl tl2))
  (print dtl)
  (setq elst (entget (car (entsel "Thay cho so: "))))
  (setq elst (subst (cons 1 (rtos dtl 2 2)) (assoc 1 elst) elst))
  (entmod elst)
  (print)
  (prompt (strcat "\nTotal area : " (rtos dtl 2 2)))
  (print)
;  (setq pt2 (getpoint "\nPoint to write: "))
;  (command "text" pt2 (/ vsize 6) "0" (rtos dtl 2 2))
);defun


  • 0

#8 phamthanhbinh

phamthanhbinh

    biết lệnh adcenter

  • Moderator
  • PipPipPipPipPipPipPip
  • 6007 Bài viết
Điểm đánh giá: 3113 (tuyệt vời)

Đã gửi 13 June 2014 - 03:15 PM

thank bác nhưng bác sửa cho e phần tính diện tích bằng cách pick vào vùng cần tính diện tích như lisp này được không ạ, phần tính diện tích của bác chỉ tính diện tích được 1 vùng, không linh hoạt lắm 

(defun c:N()
  (if (= tl nil) (progn
    (setq tl (getreal "\nDrawing scale : "))
    (setq ntl (/ 100 tl))
    (setq tl2 (* ntl ntl))
    )
  )
  (setq dtl 0)
  (setq ss (ssadd))
  (setq oslast (getvar "OSMODE"))
  (command "osnap" "")
  (print)
  (print)
  (setq pt1 (getpoint "\nPick internal point : "))
  (while (/= pt1 nil)
    (command "-boundary" pt1 "")
    (setq et (entlast))
    (ssadd et ss)
    (command "area" "e" "last")
    (setq vsize ( /(getvar "VIEWSIZE") 3 ))
    (command "hatch" "ANSI31" vsize "0" "last" "")
    (setq et (entlast))
    (ssadd et ss)
    (setq dtcon (getvar "AREA"))
    (setq dtl (+ dtcon dtl))
    (print)
    (print)
    (setq pt1 (getpoint "\nPick internal point : "))
  )
  (command "setvar" "OSMODE" oslast)
  (command "erase" ss "")
  (setq ss nil)
  (command "redraw")
  (setq dtl (/ dtl tl2))
  (print dtl)
  (setq elst (entget (car (entsel "Thay cho so: "))))
  (setq elst (subst (cons 1 (rtos dtl 2 2)) (assoc 1 elst) elst))
  (entmod elst)
  (print)
  (prompt (strcat "\nTotal area : " (rtos dtl 2 2)))
  (print)
;  (setq pt2 (getpoint "\nPoint to write: "))
;  (command "text" pt2 (/ vsize 6) "0" (rtos dtl 2 2))
);defun

Hề hề hề,

Không hiểu ý bạn hỏi.

Lisp của bác Doan Van Ha cho phép chọn nhiều diện tich nhỏ để tinh tổng diện tích của chúng rồi tay tổng diện tích này vào một text được chọn.

Tuy nhiên nó chưa đúng với cái bạn cần là phải lấy giá trị text bạn chọn trừ đi giá trị của tổng diện tích này rồi mới thay vào. Việc này có lẽ bác DoanVanHa quên đọc lại yêu cầu của bạn nên sót. Sửa lại chẳng khó gì.

Nhưng tại bài post này bạn lại chả đoái hoài gì đến kết quả này cả mà chỉ nêu thêm yêu cầu muốn chọn nhiều diện tích. Phải chăng bạn muốn mỗi lần pick diện tích thì lại chọn một text để ghi kết quả chứ không phải pick nhiều diện tích như chỉ thay một kết quả tổng như bác DoanVanHa đã hiểu????


  • 0
Chúc các quý Anh trên diễn đàn luôn khỏe, đẻ thêm được nhiều thứ để mót.

#9 sonhaxatac

sonhaxatac

    biết pan

  • Members
  • Pip
  • 8 Bài viết
Điểm đánh giá: 0 (bình thường)

Đã gửi 13 June 2014 - 03:26 PM

Hề hề hề,

Không hiểu ý bạn hỏi.

Lisp của bác Doan Van Ha cho phép chọn nhiều diện tich nhỏ để tinh tổng diện tích của chúng rồi tay tổng diện tích này vào một text được chọn.

Tuy nhiên nó chưa đúng với cái bạn cần là phải lấy giá trị text bạn chọn trừ đi giá trị của tổng diện tích này rồi mới thay vào. Việc này có lẽ bác DoanVanHa quên đọc lại yêu cầu của bạn nên sót. Sửa lại chẳng khó gì.

Nhưng tại bài post này bạn lại chả đoái hoài gì đến kết quả này cả mà chỉ nêu thêm yêu cầu muốn chọn nhiều diện tích. Phải chăng bạn muốn mỗi lần pick diện tích thì lại chọn một text để ghi kết quả chứ không phải pick nhiều diện tích như chỉ thay một kết quả tổng như bác DoanVanHa đã hiểu????

thế bác chưa thử lisp của bác Doan Van Ha rồi, lisp đấy cho phép lấy giá trị của text trừ đi giá trị diện tích vừa tính được rồi ghi kết quả đó thay cho text cũ, nhưng mỗi lần chỉ tính được diện tích của 1 hình và phải chọn đường bao của diện tích cần tính chứ không tích được vào vùng cần tính diện tích, như thế khi có 2 hình sát nhau thì rất khó chọn


  • 0

#10 Doan Van Ha

Doan Van Ha

    biết lệnh adcenter

  • CADViet Team
  • PipPipPipPipPipPipPip
  • 5447 Bài viết
Điểm đánh giá: 2624 (tuyệt vời)

Đã gửi 14 June 2014 - 10:05 AM

Cuối cùng thì bạn muốn những gì? Kiểu nào? Diễn giải rành mạch điều bạn muốn, nếu có ví dụ càng tốt, tôi xem được thì giúp.


  • 0

* Chỉ nên yêu cầu Lisp khi bạn làm việc đó mất cả ngày nhưng họ chỉ viết 1 giờ. Đừng nêu yêu cầu Lisp khi bạn chỉ làm 1 giờ nhưng bắt họ phải mất cả ngày.

* Nhờ viết lisp cũng như đi khám bệnh. Chỉ gởi căn cước và than sắp chết thì không bác sỹ nào cứu sống được.


#11 phamthanhbinh

phamthanhbinh

    biết lệnh adcenter

  • Moderator
  • PipPipPipPipPipPipPip
  • 6007 Bài viết
Điểm đánh giá: 3113 (tuyệt vời)

Đã gửi 14 June 2014 - 10:52 AM

thế bác chưa thử lisp của bác Doan Van Ha rồi, lisp đấy cho phép lấy giá trị của text trừ đi giá trị diện tích vừa tính được rồi ghi kết quả đó thay cho text cũ, nhưng mỗi lần chỉ tính được diện tích của 1 hình và phải chọn đường bao của diện tích cần tính chứ không tích được vào vùng cần tính diện tích, như thế khi có 2 hình sát nhau thì rất khó chọn

Ủa, vậy chứ cái lisp bạn post trong bài viết đó (n.lsp) là không phải của bác DoanVanHa viết à. Mình chỉ đọc cái lisp trong bài post đó và nhận xét nên cứ nghĩ rằng đó là cái bác hà đã viết và bạn yêu cầu sửa lại.

Sorry bạn và bác hà vì sự nhầm lẫn này.


  • 0
Chúc các quý Anh trên diễn đàn luôn khỏe, đẻ thêm được nhiều thứ để mót.

#12 sonhaxatac

sonhaxatac

    biết pan

  • Members
  • Pip
  • 8 Bài viết
Điểm đánh giá: 0 (bình thường)

Đã gửi 14 June 2014 - 09:10 PM

Cuối cùng thì bạn muốn những gì? Kiểu nào? Diễn giải rành mạch điều bạn muốn, nếu có ví dụ càng tốt, tôi xem được thì giúp.

cái lisp e post là lisp tính diện tích theo kiểu pick vào vùng cần tính diện tích và tính được diện tích của nhiều vùng 1 lúc( ví dụ pick vào giữa hình vuông, và pick vào giữa hình tròn chẳng hạn thì nó sẽ tính diện tích cả 2 hình cộng lại) giả sử ta được diện tích 2 hình đó là 100, sau đó chọn text để nó ghi kết quả 100 ra thay cho text có sẵn.

bây h e nhờ bác sửa hộ cái đoạn cuối, sau khi tính được diện tích 100 rồi, khi pick vào text có sẵn để điền kết quả , giả sử text đang có giá trị là 300 thì nó sẽ lấy 300 trừ đi 100 và ghi kết quả là 200.

Như lisp "ha" của bác viết lần trước thì nó đã lấy 300 - 100 rồi nhưng mà cách tính diện tích thì lại chọn đường bao hình vuông và chỉ chọn được 1 hình.


  • 0

#13 phamthanhbinh

phamthanhbinh

    biết lệnh adcenter

  • Moderator
  • PipPipPipPipPipPipPip
  • 6007 Bài viết
Điểm đánh giá: 3113 (tuyệt vời)

Đã gửi 14 June 2014 - 09:57 PM

cái lisp e post là lisp tính diện tích theo kiểu pick vào vùng cần tính diện tích và tính được diện tích của nhiều vùng 1 lúc( ví dụ pick vào giữa hình vuông, và pick vào giữa hình tròn chẳng hạn thì nó sẽ tính diện tích cả 2 hình cộng lại) giả sử ta được diện tích 2 hình đó là 100, sau đó chọn text để nó ghi kết quả 100 ra thay cho text có sẵn.

bây h e nhờ bác sửa hộ cái đoạn cuối, sau khi tính được diện tích 100 rồi, khi pick vào text có sẵn để điền kết quả , giả sử text đang có giá trị là 300 thì nó sẽ lấy 300 trừ đi 100 và ghi kết quả là 200.

Như lisp "ha" của bác viết lần trước thì nó đã lấy 300 - 100 rồi nhưng mà cách tính diện tích thì lại chọn đường bao hình vuông và chỉ chọn được 1 hình.

Hề hề hề,

Mạn phép bác DoanVanHa sửa lại cái lisp của bác , nhưng không biết có đúng ý chủ thớt không nữa.

(defun C:HA( / ent1 ent2 dt1 dt2 obj2)
 (setq ss (ssadd))
 (setq dt1 0)
 (while (setq pt1 (getpoint "\n Pick diem ben trong vung kin can tinh dien tich"))
         (command "-boundary" pt1 "")
         (setq ent1 (entlast))
         (ssadd ent1 ss)
         (setq dt1 (+ dt1 (vla-get-Area (vlax-ename->vla-object ent1))))
 )
 (setq ent2 (car (entsel "\nChon text can hieu chinh gia tri: ")))
 (setq dt2 (atof (vla-get-textstring (setq obj2 (vlax-ename->vla-object ent2)))))
 (vla-put-textstring obj2 (rtos (- dt2 dt1) 2)) 
 (command "erase" ss "")
)

  • 1
Chúc các quý Anh trên diễn đàn luôn khỏe, đẻ thêm được nhiều thứ để mót.

#14 sonhaxatac

sonhaxatac

    biết pan

  • Members
  • Pip
  • 8 Bài viết
Điểm đánh giá: 0 (bình thường)

Đã gửi 16 June 2014 - 09:25 PM

Hề hề hề,

Mạn phép bác DoanVanHa sửa lại cái lisp của bác , nhưng không biết có đúng ý chủ thớt không nữa.

đúng lisp này rồi, thank bác nhiều  :)


  • 0