Lỗi chỉnh justify trong text khi entmake text

[limfx 17]

Nhờ các anh giúp khắc phục lỗi ở tham số 72, 73 của entmake text

(entmake (list 
         (cons 0 "TEXT")
        (cons 10 p);point 
        (cons 40 2);hight 
        (cons 50 0);angle 
        (cons 1 text);content
        (cons 72 1);middle
        (cons 73 2);center
))

[huunhantvxdts 195]

29 phút trước, limfx đã nói:

Nhờ các anh giúp khắc phục lỗi ở tham số 72, 73 của entmake text

(entmake (list 
         (cons 0 "TEXT")
        (cons 10 p);point 
        (cons 40 2);hight 
        (cons 50 0);angle 
        (cons 1 text);content
        (cons 72 1);middle
        (cons 73 2);center
))

(defun MakeText (point string Height Ang justify Style Layer Color / Lst); Ang: Radial
(setq Lst (list '(0 . "TEXT")
(cons 8 (if Layer Layer (getvar "Clayer")))
(cons 62 (if Color Color 256))
(cons 10 point)
(cons 40 Height)
(cons 1 string)
(if Ang (cons 50 Ang))
(cons 7 (if Style Style (getvar "Textstyle")))
)
justify (strcase justify)
)
      (cond ((= justify "C") (setq Lst (append Lst (list (cons 72 1) (cons 11 point)))))
			((= justify "R") (setq Lst (append Lst (list (cons 72 2) (cons 11 point)))))
			((= justify "M") (setq Lst (append Lst (list (cons 72 4) (cons 11 point)))))
			((= justify "TL") (setq Lst (append Lst (list (cons 72 0) (cons 11 point) (cons 73 3)))))
			((= justify "TC") (setq Lst (append Lst (list (cons 72 1) (cons 11 point) (cons 73 3)))))
			((= justify "TR") (setq Lst (append Lst (list (cons 72 2) (cons 11 point) (cons 73 3)))))	
			((= justify "ML") (setq Lst (append Lst (list (cons 72 0) (cons 11 point) (cons 73 2)))))
			((= justify "MC") (setq Lst (append Lst (list (cons 72 1) (cons 11 point) (cons 73 2)))))
			((= justify "MR") (setq Lst (append Lst (list (cons 72 2) (cons 11 point) (cons 73 2)))))
			((= justify "BL") (setq Lst (append Lst (list (cons 72 0) (cons 11 point) (cons 73 1)))))
			((= justify "BC") (setq Lst (append Lst (list (cons 72 1) (cons 11 point) (cons 73 1)))))
			((= justify "BR") (setq Lst (append Lst (list (cons 72 2) (cons 11 point) (cons 73 1)))))
      )
     (entmakex Lst)
 )

Bạn tham khảo lisp này nhé

 

[NTHAHT 78]

1 giờ trước, limfx đã nói:

Nhờ các anh giúp khắc phục lỗi ở tham số 72, 73 của entmake text

(entmake (list 
         (cons 0 "TEXT")
        (cons 10 p);point 
        (cons 40 2);hight 
        (cons 50 0);angle 
        (cons 1 text);content
        (cons 72 1);middle
        (cons 73 2);center
))

Khi dxf_72 + dxf_73 > 0, thì bạn phải thêm dxf_11 vào.

[limfx 17]

Cảm ơn bác huunhantvxdts và NTHAHT rất nhiều!