Viết giúp lisp cad trải mặt phẳng từ hình được chọn

[dangtheanh262 0]

 
ví dụ biết 2 đường tròn đồng tâm r1 = 300 r2= 360 h bằng 60. lisp này có thể trải cái mặt chéo của nó thành mặt phẳng hình quạt. nếu có thể trải được hình khác nữa càng tốt ạ. Xin cảm ơn mọi người đã đọc bài viết <3

[cuongtk2 494]

Kết quả trải phẳng từ hình nón mẹ.

Bán kính trong : 424,25

Bán kính ngoài : 509,10

Góc mở : 254,56 độ

[dangtheanh262 0]

em viết được rồi a ạ nhưng cái em đang viết này nó đang chỉ là từ những đường thang nối liền lại chứ không phải là 1 đường arc mượt có cách nào không a nhỉ

TRAI DIEN V1.LSP

[cuongtk2 494]

(defun c:TraiNonCut (/ p1 r1 r2 h L rArc2 rArc1 theta pCenter pStart1 pStart2)
  (setq r1 (getdist "\nNhập bán kính nhỏ (r1): "))
  (setq r2 (getdist "\nNhập bán kính lớn (r2): "))
  (setq h  (getdist "\nNhập chiều cao (h): "))
  (setq pCenter (getpoint "\nChọn điểm đặt hình trải: "))

  (if (and r1 r2 h pCenter (> r2 r1))
    (progn
      ;; Tính toán thông số
      (setq L (sqrt (+ (expt h 2) (expt (- r2 r1) 2))))
      (setq rArc2 (/ (* r2 L) (- r2 r1)))
      (setq rArc1 (- rArc2 L))
      (setq theta (/ (* 2 pi r2) rArc2))

      ;; Vẽ cung lớn (Arc 2)
      (entmake
        (list
          '(0 . "ARC")
          (cons 10 pCenter)
          (cons 40 rArc2)
          (cons 50 0.0)
          (cons 51 theta)
        )
      )

      ;; Vẽ cung nhỏ (Arc 1)
      (entmake
        (list
          '(0 . "ARC")
          (cons 10 pCenter)
          (cons 40 rArc1)
          (cons 50 0.0)
          (cons 51 theta)
        )
      )

      ;; Vẽ 2 đường line nối đầu mút
      (setq pStart1 (polar pCenter 0.0 rArc1))
      (setq pEnd1   (polar pCenter 0.0 rArc2))
      (setq pStart2 (polar pCenter theta rArc1))
      (setq pEnd2   (polar pCenter theta rArc2))

      (entmake (list '(0 . "LINE") (cons 10 pStart1) (cons 11 pEnd1)))
      (entmake (list '(0 . "LINE") (cons 10 pStart2) (cons 11 pEnd2)))
    )
    (princ "\nThông số không hợp lệ (r2 phải lớn hơn r1).")
  )
  (princ)
)

Nó đơn giản vậy thôi.

[amateurday 26]

Bác Cường tài thật. Em còn chưa hiểu nghĩa là gì luôn.