Chuyển đến nội dung
Diễn đàn CADViet
Đăng nhập để thực hiện theo  
hai49c2

lisp xuat tọa độ có điều kiện

Các bài được khuyến nghị

Chào các bạn.

MÌnh có 1 yêu cầu thế này ak!

MÌnh có 1 polynie Và 2 hàng text, hàng thứ nhất là cao độ hàng thứ 2 là khoảng cách,

MỤc đích của lisp là xuất tọa độ điểm đầu, sau đó offset 1 đoạn bằng giá trị text thứ nhất  hàng thứ 2 và lấy tọa độ điểm đó, tiếp tục offset 1 đoạn bằng giá trị text thứ 2 hàng thứ 2, cứ tiếp tục như thế cho đến điểm cuối của polyline đó, sau đó xuất bảng tọa độ và cao độ sang file tẽxt hoặc exel, các bạn xem file minh họa. rất mong sự giúp đỡ của các bạn.

 

http://www.cadviet.com/upfiles/3/121099_toa_do.dwg

Chia sẻ bài đăng này


Liên kết tới bài đăng
Chia sẻ trên các trang web khác

Không bạn nào làm được lisp này sao, chỉ cần xuất được bảng trên cad cũng được, thank các bạn

sshot-1.pngketqua.png

Chia sẻ bài đăng này


Liên kết tới bài đăng
Chia sẻ trên các trang web khác

Vì không có thời gian nên không xử lý lỗi nếu chọn sai đối tượng.
Khi chọn pline, pick vào gần điểm bắt đầu

(vl-load-com)
(defun Dxf(n e) (cdr (assoc n e)))
(defun C:XTD ( / d en es f fz g i k l lh lk ls ob p st v) ; xuat toa do
    (setq es (entsel "\nChon duong polyline ") ob (vlax-ename->vla-object (car es)) p (cadr es))
    (setq st (vlax-curve-getStartPoint ob) en (vlax-curve-getEndPoint ob))
    (setq l (vlax-curve-getDistAtParam ob (vlax-curve-getEndParam ob)) d 0)
    (setq fz 0.001) ; sai so lam tron k/c
    (if (< (distance p st) (distance p en))
        (setq d 0 k 1)
        (setq d l k -1)
    )
    (princ "\nChon text :")
    (setq ls (vl-remove-if 'listp (mapcar 'cadr (ssnamex (ssget '((0 . "TEXT") ))))))
    (foreach e ls
        (setq g (entget e) v (list (car (Dxf 10 g)) (Dxf 1 g)))
        (if (= 0 (Dxf 50 g))
            (setq lk (cons v lk))
            (setq lh (cons v lh))
        ))
    (setq    lk (vl-sort lk (function (lambda (e1 e2) (< (car e1) (car e2))))))
    (setq    lh (vl-sort lh (function (lambda (e1 e2) (< (car e1) (car e2))))))
    (setq f (open (strcat (getvar "DWGPREFIX") "Toado.txt") "w") i 0)
    (write-line "X\tY\t\H" f)
    (while (and (nth i lh) (< d (+ l fz)) (>= d (- fz)))
        (if (equal d 0 fz) (setq p st)
            (if (equal d l fz) (setq p en)
                (setq p (vlax-curve-getPointAtDist ob d))))
        (write-line (strcat (rtos (cadr p) 2 3) "\t"(rtos (car p) 2 3) "\t" (cadr(nth i lh))) f)
        (setq d (+ d (* k (atof (cadr(nth i lk))))) i (1+ i))
    )
    (close f)
)
  • Vote tăng 1

Chia sẻ bài đăng này


Liên kết tới bài đăng
Chia sẻ trên các trang web khác

 

Vì không có thời gian nên không xử lý lỗi nếu chọn sai đối tượng.

Khi chọn pline, pick vào gần điểm bắt đầu

(vl-load-com)
(defun Dxf(n e) (cdr (assoc n e)))
(defun C:XTD ( / d en es f fz g i k l lh lk ls ob p st v) ; xuat toa do
    (setq es (entsel "\nChon duong polyline ") ob (vlax-ename->vla-object (car es)) p (cadr es))
    (setq st (vlax-curve-getStartPoint ob) en (vlax-curve-getEndPoint ob))
    (setq l (vlax-curve-getDistAtParam ob (vlax-curve-getEndParam ob)) d 0)
    (setq fz 0.001) ; sai so lam tron k/c
    (if (< (distance p st) (distance p en))
        (setq d 0 k 1)
        (setq d l k -1)
    )
    (princ "\nChon text :")
    (setq ls (vl-remove-if 'listp (mapcar 'cadr (ssnamex (ssget '((0 . "TEXT") ))))))
    (foreach e ls
        (setq g (entget e) v (list (car (Dxf 10 g)) (Dxf 1 g)))
        (if (= 0 (Dxf 50 g))
            (setq lk (cons v lk))
            (setq lh (cons v lh))
        ))
    (setq    lk (vl-sort lk (function (lambda (e1 e2) (< (car e1) (car e2))))))
    (setq    lh (vl-sort lh (function (lambda (e1 e2) (< (car e1) (car e2))))))
    (setq f (open (strcat (getvar "DWGPREFIX") "Toado.txt") "w") i 0)
    (write-line "X\tY\t\H" f)
    (while (and (nth i lh) (< d (+ l fz)) (>= d (- fz)))
        (if (equal d 0 fz) (setq p st)
            (if (equal d l fz) (setq p en)
                (setq p (vlax-curve-getPointAtDist ob d))))
        (write-line (strcat (rtos (cadr p) 2 3) "\t"(rtos (car p) 2 3) "\t" (cadr(nth i lh))) f)
        (setq d (+ d (* k (atof (cadr(nth i lk))))) i (1+ i))
    )
    (close f)
)

Cảm ơn bạn rất nhiều, Phiền bạn chỉnh giúp mình 1 chút, là chuyển về đúng toạ độ X Y của cad, trong file yêu cầu cũ  mình lại chuyển toạ độ X sang Y và Y sang X.

Chúc bạn mạnh khoẻ và hạn phúc.

Chia sẻ bài đăng này


Liên kết tới bài đăng
Chia sẻ trên các trang web khác

Bạn sửa dòng

(write-line (strcat (rtos (cadr p) 2 3) "\t"(rtos (car p) 2 3) "\t" (cadr(nth i lh))) f)

thành

(write-line (strcat (rtos (car p) 2 3) "\t"(rtos (cadr p) 2 3) "\t" (cadr(nth i lh))) f)

  • Vote tăng 1

Chia sẻ bài đăng này


Liên kết tới bài đăng
Chia sẻ trên các trang web khác

Bạn sửa dòng

(write-line (strcat (rtos (cadr p) 2 3) "\t"(rtos (car p) 2 3) "\t" (cadr(nth i lh))) f)

thành

(write-line (strcat (rtos (car p) 2 3) "\t"(rtos (cadr p) 2 3) "\t" (cadr(nth i lh))) f)

Làm phiền bạn 1 chút nữa là bạn có thể chỉnh sủa lisp để sau khi chọn text xong enter thì lisp chưa xuất tọa độ luôn mà cho ta lựa chọn có tiếp tục không, 1 là có ( tiếp tục chọn plyline thứ 2, text thứ 2.......) và 0 là xuất tọa độ ra text.

tại mình muốn xuất tọa độ của nhiều polyline. cảm ơn bạn nhiều.

Chia sẻ bài đăng này


Liên kết tới bài đăng
Chia sẻ trên các trang web khác

Chọn lần lượt polyline, text. Khi nào chọn xong thì enter.
Trong code có ghi chú để bạn sửa cho phù hợp

(vl-load-com)
(defun Dxf(n e) (cdr (assoc n e)))

(defun C:XTD ( / d en es f fz g i n k l lh lk ls ob p st v) ; xuat toa do
    (setq f (open (strcat (getvar "DWGPREFIX") "Toado.txt") "w") n 0)
    (setq fz 0.001) ; sai so lam tron k/c
    (while (setq es (entsel "\nChon duong polyline "))
        (setq ob (vlax-ename->vla-object (car es)) p (cadr es))
        (setq st (vlax-curve-getStartPoint ob) en (vlax-curve-getEndPoint ob))
        (setq l (vlax-curve-getDistAtParam ob (vlax-curve-getEndParam ob)) d 0)
        (setq     i 0 lh '() lk '() n (1+ n))
        (if (< (distance p st) (distance p en))
            (setq d 0 k 1)
            (setq d l k -1)
        )
        (princ "\nChon text :")
        (setq ls (vl-remove-if 'listp (mapcar 'cadr (ssnamex (ssget '((0 . "TEXT") ))))))
        (foreach e ls
            (setq g (entget e) v (list (car (Dxf 10 g)) (Dxf 1 g)))
            (if (= 0 (Dxf 50 g))
                (setq lk (cons v lk))
                (setq lh (cons v lh))
            ))
        (setq    lk (vl-sort lk (function (lambda (e1 e2) (< (car e1) (car e2))))))
        (setq    lh (vl-sort lh (function (lambda (e1 e2) (< (car e1) (car e2))))))
        (write-line (strcat "Duong thu " (itoa n)) f) ; Neu khong can thi xoa dong nay
        (write-line "X\tY\t\H" f); Neu xoa dong tren thi dua dong nay len sau dong (setq f ...)
        (while (and (nth i lh) (< d (+ l fz)) (>= d (- fz)))
            (if (equal d 0 fz) (setq p st)
                (if (equal d l fz) (setq p en)
                    (setq p (vlax-curve-getPointAtDist ob d))))
            (write-line (strcat (rtos (cadr p) 2 3) "\t"(rtos (car p) 2 3) "\t" (cadr(nth i lh))) f)
            (setq d (+ d (if (nth i lk) (* k (atof (cadr(nth i lk)))) 0)) i (1+ i))
        )
    )
    (close f)
)

 
  • Vote tăng 1

Chia sẻ bài đăng này


Liên kết tới bài đăng
Chia sẻ trên các trang web khác

Tạo một tài khoản hoặc đăng nhập để nhận xét

Bạn cần phải là một thành viên để lại một bình luận

Tạo tài khoản

Đăng ký một tài khoản mới trong cộng đồng của chúng tôi. Điều đó dễ mà.

Đăng ký tài khoản mới

Đăng nhập

Bạn có sẵn sàng để tạo một tài khoản ? Đăng nhập tại đây.

Đăng nhập ngay

Đăng nhập để thực hiện theo  

×