Đến nội dung


Hình ảnh
* - - - - 1 Bình chọn

xin gúp đỡ lisp ve đường tâm


  • Please log in to reply
33 replies to this topic

#21 Tue_NV

Tue_NV

    KS Võ Quang Tuệ

  • Moderator
  • PipPipPipPipPipPipPip
  • 4296 Bài viết
Điểm đánh giá: 3804 (đỉnh cao)

Đã gửi 25 August 2013 - 10:24 AM

cảm ơn anh tainguyen79 rất nhiều! bây giờ đỡ phải vẽ Pline và vẽ lại tâm nữa rồi. à có thể sửa được để chỉ cần chọn 2 mép bên đường (bằng đường Pline) là vẽ luôn cho mình tim không nhỉ?

 

  89068_untitled.jpg

 

Bạn  sử dụng Lisp timsong (tìm tim sông) của Tue_NV đã viết ở đây : 

http://www.cadviet.c...yeu-cau/page-99

Bài viết số 1967


  • 1

#22 TaiNguyen79

TaiNguyen79

    biết vẽ ellipse

  • Members
  • PipPip
  • 51 Bài viết
Điểm đánh giá: 24 (tàm tạm)

Đã gửi 25 August 2013 - 03:44 PM

Bạn  sử dụng Lisp timsong (tìm tim sông) của Tue_NV đã viết ở đây : 
http://www.cadviet.c...yeu-cau/page-99
Bài viết số 1967

Góp ý chút nha : chia tim chưa chính xác so với chia thủ công.
Với lại nếu chọn ngược lại pl2 rồi pl1 sẽ cho ra tim khác với pl1 rồi pl2.
  • 1

#23 hoangkimoanh

hoangkimoanh

    biết vẽ spline

  • Members
  • PipPip
  • 92 Bài viết
Điểm đánh giá: 2 (bình thường)

Đã gửi 25 August 2013 - 10:13 PM

đúng rồi, nó chỉ tương đối đúng với 2 đường song song, còn 2 đường zic zac thì không đúng!


  • 0

#24 Tue_NV

Tue_NV

    KS Võ Quang Tuệ

  • Moderator
  • PipPipPipPipPipPipPip
  • 4296 Bài viết
Điểm đánh giá: 3804 (đỉnh cao)

Đã gửi 26 August 2013 - 03:01 AM

Góp ý chút nha : chia tim chưa chính xác so với chia thủ công.
Với lại nếu chọn ngược lại pl2 rồi pl1 sẽ cho ra tim khác với pl1 rồi pl2.

 

đúng rồi, nó chỉ tương đối đúng với 2 đường song song, còn 2 đường zic zac thì không đúng!

 

Vậy theo 2 bạn, chia thủ công như thế nào cho đúng??


  • 0

#25 TaiNguyen79

TaiNguyen79

    biết vẽ ellipse

  • Members
  • PipPip
  • 51 Bài viết
Điểm đánh giá: 24 (tàm tạm)

Đã gửi 26 August 2013 - 07:22 AM

Vậy theo 2 bạn, chia thủ công như thế nào cho đúng??

Chia tim từng cặp đoạn thẳng (Dùng pháp vector chính xác hơn là dùng đường trung tuyến). Rồi giao hội tim của chúng lại (chamfer) , nếu không sẽ bị sai tại góc ngoặt của tim tuyến.
  • 0

#26 hoangkimoanh

hoangkimoanh

    biết vẽ spline

  • Members
  • PipPip
  • 92 Bài viết
Điểm đánh giá: 2 (bình thường)

Đã gửi 26 August 2013 - 04:08 PM

em làm lại với cái code của anh Tue thì có vẻ tương đối đúng, mà như vậy là được rồi, lệch không đáng kể và cũng không ai kiểm tra kỹ quá như vậy. cảm ơn các anh đã nhiệt tình giúp đỡ, cả 3 cách đều có thể áp dụng được! :)


  • 0

#27 790312

790312

    biết lệnh fillet

  • Members
  • PipPipPipPip
  • 204 Bài viết
Điểm đánh giá: 4 (bình thường)

Đã gửi 05 May 2014 - 07:39 PM

Đây là lisp vẽ đường tâm của 2 đường cong hở, của Alan J. Thompson, khá là hay.

 

; Draw (LW)Polyline between two selected curves (at midpoint of vertices).
(defun c:LBL (/ foo AT:GetSel _pnts _pline _lwpline _dist e1 e2)
 (vl-load-com)
 (defun foo (e)
  (and (wcmatch (cdr (assoc 0 (entget (car e)))) "LINE,*POLYLINE,SPLINE")
   (not (vlax-curve-isClosed (car e)))))
 (defun AT:GetSel (meth msg fnc / ent)
  (while
   (progn
    (setvar 'ERRNO 0)
    (setq ent (meth (cond (msg) ("\nSelect object: "))))
    (cond
   ((eq (getvar 'ERRNO) 7) (princ "\nMissed, try again."))
     ((eq (type (car ent)) 'ENAME)
      (if (and fnc (not (fnc ent)))
       (princ "\nInvalid object!"))))))
  ent)
 (defun _pnts (e / p l)
  (if e
   (cond
    ((wcmatch (cdr (assoc 0 (entget e))) "ARC,LINE,SPLINE")
     (list (vlax-curve-getStartPoint e) (vlax-curve-getEndPoint e)))
    ((wcmatch (cdr (assoc 0 (entget e))) "*POLYLINE")
     (repeat (setq p (1+ (fix (vlax-curve-getEndParam e))))
      (setq l (cons (vlax-curve-getPointAtParam e (setq p (1- p))) l)))))))
 (defun _pline (lst)
  (if
   (and
    (> (length lst) 1)
    (entmakex '((0 . "POLYLINE") (10 0. 0. 0.) (70 . 8)))
    (foreach x lst (entmakex (list '(0 . "VERTEX") (cons 10 x) '(70 . 32)))))
   (cdr (assoc 330 (entget (entmakex '((0 . "SEQEND"))))))))
 (defun _lwpline (lst)
  (if (> (length lst) 1)
   (entmakex (append
     (list '(0 . "LWPOLYLINE") '(100 . "AcDbEntity") '(100 . "AcDbPolyline") (cons 90 (length lst)) (cons 70 (* (getvar 'plinegen) 128)))
     (mapcar (function (lambda (p) (list 10 (car p) (cadr p)))) lst)))))
 (defun _dist (a b)
  (distance (list (car a) (cadr a)) (list (car b) (cadr b))))
  (if
   (and
    (setq e1 (_pnts (car (AT:GetSel entsel "\nSelect first open curve: " foo))))
    (setq e2 (_pnts (car (AT:GetSel entsel "\nSelect next open curve: " foo))))
    (not (initget 0 "Lwpolyline Polyline"))
    (setq *LBL:Opt* (cond ((getkword (strcat "\nSpecify line to draw: [Lwpolyline/Polyline] <" (cond (*LBL:Opt*) ((setq *LBL:Opt* "Lwpolyline"))) ">: "))) (*LBL:Opt*))))
   ((if (eq *LBL:Opt* "Lwpolyline") _lwpline _pline)
    (vl-remove nil
     (mapcar (function (lambda(a b) 
   (if (and a b (not (grdraw (trans a 0 1) (trans b 0 1) 1 1)))
    (mapcar (function (lambda (a b) (/ (+ a b) 2.))) a b))))
       e1
      (if (< (_dist (car e1) (car e2)) (_dist (car e1) (last e2))) e2 (reverse e2))))))
 (princ))
 

Bác Hà thêm chức năng cho đoạn lisp này giùm mình với:

Sau khi chọn 2 đường có sẵn rồi sẽ vẽ đường tâm sau đó xoá 2 đường gốc,đổi tên đường mới thành tên DUONG TAM,nếu chưa có DUONG TAM thì tạo mới đường này có thuộc tính như sau:color là màu số 1.LINETYPE là Continuous.LINEWEIGHT là 0.4.

Cảm ơn bác trước.


  • 0

#28 Doan Van Ha

Doan Van Ha

    biết lệnh adcenter

  • CADViet Team
  • PipPipPipPipPipPipPip
  • 5447 Bài viết
Điểm đánh giá: 2624 (tuyệt vời)

Đã gửi 06 May 2014 - 10:55 AM

Bạn muốn Layer tên gì, Linetype ra sao, Lineweight như thế nào, color xanh/đỏ/tím/vàng thì cứ việc tạo layer có các các tính chất đó rồi set nó thành current. Sau đó dùng lisp là OK.

Lisp này của "người ta" nên ngại sửa lắm.


  • 1

* Chỉ nên yêu cầu Lisp khi bạn làm việc đó mất cả ngày nhưng họ chỉ viết 1 giờ. Đừng nêu yêu cầu Lisp khi bạn chỉ làm 1 giờ nhưng bắt họ phải mất cả ngày.

* Nhờ viết lisp cũng như đi khám bệnh. Chỉ gởi căn cước và than sắp chết thì không bác sỹ nào cứu sống được.


#29 790312

790312

    biết lệnh fillet

  • Members
  • PipPipPipPip
  • 204 Bài viết
Điểm đánh giá: 4 (bình thường)

Đã gửi 06 May 2014 - 11:00 AM

Bạn muốn Layer tên gì, Linetype ra sao, Lineweight như thế nào, color xanh/đỏ/tím/vàng thì cứ việc tạo layer có các các tính chất đó rồi set nó thành current. Sau đó dùng lisp là OK.

Lisp này của "người ta" nên ngại sửa lắm.

E không rành về lisp bác ah.Nếu ngại bác sửa giúp sau khi vẽ đường tâm thì xoá 2 đường biên đi giùm e với.Thanks.


  • 0

#30 Doan Van Ha

Doan Van Ha

    biết lệnh adcenter

  • CADViet Team
  • PipPipPipPipPipPipPip
  • 5447 Bài viết
Điểm đánh giá: 2624 (tuyệt vời)

Đã gửi 06 May 2014 - 11:20 AM

Đây! Sau khi vẽ đường tâm thì xóa 2 đường biên.

http://www.cadviet.c...e_duong_tam.lsp


  • 1

* Chỉ nên yêu cầu Lisp khi bạn làm việc đó mất cả ngày nhưng họ chỉ viết 1 giờ. Đừng nêu yêu cầu Lisp khi bạn chỉ làm 1 giờ nhưng bắt họ phải mất cả ngày.

* Nhờ viết lisp cũng như đi khám bệnh. Chỉ gởi căn cước và than sắp chết thì không bác sỹ nào cứu sống được.


#31 790312

790312

    biết lệnh fillet

  • Members
  • PipPipPipPip
  • 204 Bài viết
Điểm đánh giá: 4 (bình thường)

Đã gửi 06 May 2014 - 01:56 PM

Đây! Sau khi vẽ đường tâm thì xóa 2 đường biên.

http://www.cadviet.c...e_duong_tam.lsp

Không down được bác ơi.Bác xem lại giúp e với.Thanks.


  • 0

#32 Doan Van Ha

Doan Van Ha

    biết lệnh adcenter

  • CADViet Team
  • PipPipPipPipPipPipPip
  • 5447 Bài viết
Điểm đánh giá: 2624 (tuyệt vời)

Đã gửi 06 May 2014 - 02:02 PM

Forum dạo này bị sao ấy. Thử down thừ đây xem:

;; free lisp from cadviet.com
;;; this lisp was downloaded from http://www.cadviet.com/forum/topic/77029-xin-gup-do-lisp-ve-duong-tam/
; Draw (LW)Polyline between two selected curves (at midpoint of vertices).
(defun c:LBL ( / foo AT:GetSel _pnts _pline _lwpline _dist e1 e2 xx yy)
 (vl-load-com)
 (defun foo (e)
  (and (wcmatch (cdr (assoc 0 (entget (car e)))) "LINE,*POLYLINE,SPLINE")
   (not (vlax-curve-isClosed (car e)))))
 (defun AT:GetSel (meth msg fnc / ent)
  (while
   (progn
    (setvar 'ERRNO 0)
    (setq ent (meth (cond (msg) ("\nSelect object: "))))
    (cond
   ((eq (getvar 'ERRNO) 7) (princ "\nMissed, try again."))
     ((eq (type (car ent)) 'ENAME)
      (if (and fnc (not (fnc ent)))
       (princ "\nInvalid object!"))))))
  ent)
 (defun _pnts (e / p l)
  (if e
   (cond
    ((wcmatch (cdr (assoc 0 (entget e))) "ARC,LINE,SPLINE")
     (list (vlax-curve-getStartPoint e) (vlax-curve-getEndPoint e)))
    ((wcmatch (cdr (assoc 0 (entget e))) "*POLYLINE")
     (repeat (setq p (1+ (fix (vlax-curve-getEndParam e))))
      (setq l (cons (vlax-curve-getPointAtParam e (setq p (1- p))) l)))))))
 (defun _pline (lst)
  (if
   (and
    (> (length lst) 1)
    (entmakex '((0 . "POLYLINE") (10 0. 0. 0.) (70 . 8)))
    (foreach x lst (entmakex (list '(0 . "VERTEX") (cons 10 x) '(70 . 32)))))
   (cdr (assoc 330 (entget (entmakex '((0 . "SEQEND"))))))))
 (defun _lwpline (lst)
  (if (> (length lst) 1)
   (entmakex (append
     (list '(0 . "LWPOLYLINE") '(100 . "AcDbEntity") '(100 . "AcDbPolyline") (cons 90 (length lst)) (cons 70 (* (getvar 'plinegen) 128)))
     (mapcar (function (lambda (p) (list 10 (car p) (cadr p)))) lst)))))
 (defun _dist (a b)
  (distance (list (car a) (cadr a)) (list (car b) (cadr b))))
 (if
  (and
   (setq e1 (_pnts (setq xx (car (AT:GetSel entsel "\nSelect first open curve: " foo)))))
   (setq e2 (_pnts (setq yy (car (AT:GetSel entsel "\nSelect next open curve: " foo)))))
   (not (initget 0 "Lwpolyline Polyline"))
   (setq *LBL:Opt* (cond ((getkword (strcat "\nSpecify line to draw: [Lwpolyline/Polyline] <" (cond (*LBL:Opt*) ((setq *LBL:Opt* "Lwpolyline"))) ">: "))) (*LBL:Opt*))))
  ((if (eq *LBL:Opt* "Lwpolyline") _lwpline _pline)
   (vl-remove nil
    (mapcar (function (lambda(a b)
       (if (and a b (not (grdraw (trans a 0 1) (trans b 0 1) 1 1)))
        (mapcar (function (lambda (a b) (/ (+ a b) 2.))) a b))))
      e1
     (if (< (_dist (car e1) (car e2)) (_dist (car e1) (last e2))) e2 (reverse e2))))))
 (if (and xx yy) (progn (entdel xx) (entdel yy)))
 (princ))
 


  • 1

* Chỉ nên yêu cầu Lisp khi bạn làm việc đó mất cả ngày nhưng họ chỉ viết 1 giờ. Đừng nêu yêu cầu Lisp khi bạn chỉ làm 1 giờ nhưng bắt họ phải mất cả ngày.

* Nhờ viết lisp cũng như đi khám bệnh. Chỉ gởi căn cước và than sắp chết thì không bác sỹ nào cứu sống được.


#33 sai_sai710

sai_sai710

    Chưa sử dụng CAD

  • Members
  • Pip
  • 3 Bài viết
Điểm đánh giá: -1 (bình thường)

Đã gửi 19 March 2015 - 02:11 PM

Lệnh gọi để vẽ là gì vậy bạn


  • -1

#34 Doan Van Ha

Doan Van Ha

    biết lệnh adcenter

  • CADViet Team
  • PipPipPipPipPipPipPip
  • 5447 Bài viết
Điểm đánh giá: 2624 (tuyệt vời)

Đã gửi 19 March 2015 - 02:48 PM

Lệnh LBL


  • 0

* Chỉ nên yêu cầu Lisp khi bạn làm việc đó mất cả ngày nhưng họ chỉ viết 1 giờ. Đừng nêu yêu cầu Lisp khi bạn chỉ làm 1 giờ nhưng bắt họ phải mất cả ngày.

* Nhờ viết lisp cũng như đi khám bệnh. Chỉ gởi căn cước và than sắp chết thì không bác sỹ nào cứu sống được.