Lisp copy nhanh đối tượng theo nhiều khoảng cách

[hoanghi 0]

Mình đang vẽ các lỗ bulông trên mặt thép nhưng copy rất lâu. Có bạn nào có cách nào vẽ nhanh hơn không ? Hoặc viết hộ dùm mình cái lisp là chọn đối tượng xong , mỗi lần nhập khoảng cách thì sẽ copy đối tượng đó đến vị trí mới . Các khoảng cách sẽ được tính từ đối tượng vừa mới copy kế nó . Thank nhiều ! 

[Tot77 508]

Bạn dùng cái này. Sau khi copy xong nếu bạn dùng lệnh khác mà có select objects thì có thể đánh chữ "P" để lấy các đối tượng cuối cùng.

 

(defun c:cpy(/ ss pt hg os el en)
  (prompt "\nChon cac doi tuong de copy:")
  (setq ss (ssget) 
pt (getpoint "\nDiem goc:")
hg (getangle pt "\nTheo huong:")
os (getvar 'osmode))
  (setvar 'osmode 0)
  (while (setq kc (getreal "\nKhoang cach:"))
    (setq el (entlast))
    (command "copy" ss "" pt (polar pt hg kc))
    (setq ss (ssadd))
    (while (setq en (entnext el))
      (ssadd en ss)
      (setq el en))
  ) 
  (command "select" ss "")
  (setvar 'osmode os) (princ)
)

[hoanghi 0]

Thanh bạn nhiều. Dùng rất chi là tiện luôn. :D

[toiyeuvietnam 0]

 

Bạn dùng cái này. Sau khi copy xong nếu bạn dùng lệnh khác mà có select objects thì có thể đánh chữ "P" để lấy các đối tượng cuối cùng.

 

(defun c:cpy(/ ss pt hg os el en)
  (prompt "\nChon cac doi tuong de copy:")
  (setq ss (ssget) 
pt (getpoint "\nDiem goc:")
hg (getangle pt "\nTheo huong:")
os (getvar 'osmode))
  (setvar 'osmode 0)
  (while (setq kc (getreal "\nKhoang cach:"))
    (setq el (entlast))
    (command "copy" ss "" pt (polar pt hg kc))
    (setq ss (ssadd))
    (while (setq en (entnext el))
      (ssadd en ss)
      (setq el en))
  ) 
  (command "select" ss "")
  (setvar 'osmode os) (princ)
)

Tot77 ơi, cái này bạn có thể thêm chức năng lưu biến khoảng cách được không? cảm ỏn nhiều

[Tot77 508]

Lưu biến đây, muốn kết thúc thì bấm Z.

 

(defun c:cpy(/ ss pt hg os el en kc)
  (prompt "\nChon cac doi tuong de copy:")
  (setq ss (ssget)
pt (getpoint "\nDiem goc:")
hg (getangle pt "\nTheo huong:")
tt t
os (getvar 'osmode))
  (setvar 'osmode 0)
  
  (while tt    
    (setq kc (getstring (strcat "\nKhoang cach <"
     (rtos (if (not kcach) (setq kcach 1) kcach)) " / nhan Z de ket thuc>:")))
    (cond ((and (/= kc "") (/= (strcase kc) "Z")) (setq kcach (atof kc)))
 ((= (strcase kc) "Z") (setq tt nil)))    
    (if tt
      (progn
(setq el (entlast))
(command "copy" ss "" pt (polar pt hg kcach))
(setq ss (ssadd))
(while (setq en (entnext el))
 (ssadd en ss)
 (setq el en))
     ) )
  )
  (command "select" ss "")
  (setvar 'osmode os) (princ)
)
 

[toiyeuvietnam 0]

oh, cảm ơn Tot77 nhiều nhé, làm rất ổn!