Nhờ Chỉnh Viết Lisp Copy Mtext Ra Nhiều Layout 1 Lần

[PHAPLUONG 4]

Em xin nhờ các bác viết giúp lisp với công dụng như sau:

1. Tạo Mtext trong layout đầu tiên

2. gõ lệnh ==> chọn Mtext thì tự động copy mtext đã tạo ra tất cả các layout còn lại với cùng toaj độ

[KangKung 250]

Lisp theo yêu cầu của bạn đây

 

(defun c:CopyToLayouts (/ *error* ss)

(princ "\rCOPYTOLAYOUTS ")

(vl-load-com)

 

(defun *error* (msg)

(if acDoc (vla-endundomark acDoc))

(cond ((not msg)) ; Normal exit

((member msg '("Function cancelled" "quit / exit abort"))) ; <esc> or (quit)

((princ (strcat "\n** Error: " msg " ** ")))) ; Fatal error, display it

(princ))

 

(prompt "\nSelect objects to copy to layouts: ")

(if (setq ss (ssget "_:L"))

((lambda (acDoc / oItemList oCurLayout)

(vla-startundomark acDoc)

(vlax-for oItem (setq ss (vla-get-activeselectionset acDoc))

(setq oItemList (cons oItem oItemList)))

(vlax-for oLayout (vla-get-layouts acDoc)

(if (and (/= (cond

(oCurLayout)

((setq oCurLayout (vla-get-activeLayout acDoc))))

oLayout)

(/= "Model" (vla-get-name oLayout)))

(vlax-invoke

acDoc

"copyobjects"

oItemList

(vla-get-block oLayout))))

(vla-delete ss)

(*error* nil))

(vla-get-activedocument (vlax-get-acad-object)))

(prompt "\n** Nothing selected ** "))

(princ))

[PHAPLUONG 4]

Tuyệt vời

Cảm ơn bác!

[quocmanh04tt 635]

Tuyệt vời. Nhưng bác KangKung viết bằng "Vê lờ" nên hơi dài và bỏ qua Layer Lock. Dùng entmake gọn hơn:

(defun c:tt  (/ els mte i tab)
 (and (not (eq (strcase (setq tab (getvar 'CTAB))) "MODEL"))
      (setq mte (ssget '((0 . "MTEXT"))))
      (repeat (setq i (sslength mte))
       (setq els (entget (ssname mte (setq i (1- i)))))
       (foreach lay (vl-remove tab (layoutlist))
        (entmake (subst (cons 410 lay) (assoc 410 els) els)))))
 (princ))

[PHAPLUONG 4]

Tuyệt vời. Nhưng bác KangKung viết bằng "Vê lờ" nên hơi dài và bỏ qua Layer Lock. Dùng entmake gọn hơn:

(defun c:tt  (/ els mte i tab)

 (and (not (eq (strcase (setq tab (getvar 'CTAB))) "MODEL"))

      (setq mte (ssget '((0 . "MTEXT"))))

      (repeat (setq i (sslength mte))

       (setq els (entget (ssname mte (setq i (1- i)))))

       (foreach lay (vl-remove tab (layoutlist))

        (entmake (subst (cons 410 lay) (assoc 410 els) els)))))

 (princ))

Cảm ơn bác nhiệt tình giúp đỡ. Lisp của bác ngắn gọn mà đáp ứng đúng nhu cầu ban đầu của e là chỉ copy Mtext, còn lisp của bác @KhangKung thì có thể copy các đối tượng khác, vượt yêu cầu của e. Cảm ơn 2 bác

[quang_lac 32]

@Phapluong nếu sheet set của bạn mà có subset và bạn lấy fied title của sheet thì khi copy text các fiel này ko nhảy theo mà vẫn lấy theo giá trị đầu tiên khi tạo

[PHAPLUONG 4]

@Phapluong nếu sheet set của bạn mà có subset và bạn lấy fied title của sheet thì khi copy text các fiel này ko nhảy theo mà vẫn lấy theo giá trị đầu tiên khi tạo

Mình thấy fiel vẫn nhảy theo sheet mà bạn