Xác Định 2 Đỉnh Đối Nhau Của Khung Tên Được Xref

[ThanhDattdk 3]

Xin chào các bác. Em muốn xác định 2 đỉnh đối nhau của khung tên được Xref để làm lisp IN [ lisp in chỉ quét khung tên được chọn thì tự bắt 2 đỉnh để preview hoặc in với đk mình đã ADDlayout từ trước ]. Mong các bác chỉ giáo thêm, em xin cảm ơn

[Bee 154]

Xin chào các bác. Em muốn xác định 2 đỉnh đối nhau của khung tên được Xref để làm lisp IN [ lisp in chỉ quét khung tên được chọn thì tự bắt 2 đỉnh để preview hoặc in với đk mình đã ADDlayout từ trước ]. Mong các bác chỉ giáo thêm, em xin cảm ơn

Có thể dùng box của Lee nhé. ^_^

Code here:

(defun c:test ( / ent )
    (if (setq ent (car (entsel)))
        (entmake
            (append
               '(
                    (000 . "LWPOLYLINE")
                    (100 . "AcDbEntity")
                    (100 . "AcDbPolyline")
                    (090 . 4)
                    (070 . 1)
                )
                (mapcar '(lambda ( p ) (cons 10 p)) (LM:boundingbox (vlax-ename->vla-object ent)))
            )
        )
    )
    (princ)
)
(vl-load-com) (princ)

;; Bounding Box  -  Lee Mac
;; Returns the point list describing the rectangular frame bounding the supplied object.
;; obj - [vla] VLA-Object

(defun LM:boundingbox ( obj / a b lst )
    (if
        (and
            (vlax-method-applicable-p obj 'getboundingbox)
            (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-getboundingbox (list obj 'a 'b))))
            (setq lst (mapcar 'vlax-safearray->list (list a b)))
        )
        (mapcar '(lambda ( a ) (mapcar '(lambda ( b ) ((eval b) lst)) a))
           '(
                (caar   cadar)
                (caadr  cadar)
                (caadr cadadr)
                (caar  cadadr)
            )
        )
    )
)