[Đã xong] - Tự động bật - tắt chế độ gõ tiếng việt trong CAD

[ThuyLinh313 156]

Hihi, cảm ơn DVH, mình chưa có nhiều kinh nghiệm post bài nên thiếu lung tung hết cả.

@Nhoclangbat. em down lại ver2.0 nhé. lần này đảm bảo chạy ngon. hỗ trợ tốt từ cad 2009 trở đi :D

[nhoclangbat 392]

lsp đã dùng tốt chị ah, thank chị nhiều, nhưng em thấy còn 1 xíu nữa ^^, vd em đang để mã unicode khi đánh text trong cad font "vni-" đúng là nó tự chuyển sang mã vni windowns nhưng khi đánh xong ok, theo lsp của chị giải thích nó sẽ tự trả về ban đầu là unicode nhưng của em nó ko trả về nó nằm ở mã vni windowns lun, tại máy em hả chị :D

[ThuyLinh313 156]

Lisp này chỉ trả lại chế độ gõ Tiếng Anh cho Unikey thôi, không trả lại thiết lập bảng mã nhoclangbat ạ.

[thoxayncp 0]

Tớ chưa dùng, nhưng thật là tuyệt vời! hehe down ngay!

;) ;)

[tien2005 245]

Thanks.

Trong lisp của Bạn chuyển chế độ gõ Anh/Việt bằng cách sendkey CTRL+SHIFT. Tuy nhiên trên máy người sẽ còn các úng dụng khác, cac ứng dụng này có các lệnh dùng phím CTRL+SHIFT. Do đó họ sẽ chọn theo cách ALT+Z cho chương trình Unikey

 

Vì vậy Bạn có thể thêm cách ALT+Z vào lisp được không hoặc cho mình biết mã của phím ALT+Z trong lisp là gì để mình điều chỉnh cho phù hợp với cách sử dụng

p/s: Theo mình là thêm dòng lệnh sendkey ALT+Z sau lệnh sendkey CTRL+SHIFT,vì lisp chỉ có tác dụng trên AuotoCAD, nếu CTRL+SHIFT không được thì ALT+Z cũng đã sẵn sàng ^_^

 

àh, co thêm vấn đề này nữa:

Nếu có 3 text 3 kiểu font khác nhau thì khi dùng lệnh của lisp (chỉ trong 1 lần enter lênh) để sửa cho từng text thì nó sẽ hiểu và chọn bảng mã cho text đầu tiên, đến text 2, 3 thi có bẩng mã khác nhưng nó vẫn dùng bẩng mã của text đầu). Nếu được Bạn cho kiểm tra bảng mã trong từng text được chọn thì sẽ hay hơn

[ThuyLinh313 156]

Cú pháp cho Alt+Z như sau: (sendkeys "%{Z}")

Bạn có thể tham khảo thêm trong link này: http://msdn.microsof...s.sendkeys.aspx

 

Vấn đề thứ 2 bạn đề cập mình cũng đã gặp phải và vẫn đang tìm cách bổ sung nhưng chưa làm được. Có thể sẽ không bao giờ làm được :'(

[phamthanhbinh 3147]

Hihi, cảm ơn DVH, mình chưa có nhiều kinh nghiệm post bài nên thiếu lung tung hết cả.

@Nhoclangbat. em down lại ver2.0 nhé. lần này đảm bảo chạy ngon. hỗ trợ tốt từ cad 2009 trở đi :D

Hề hề hề,

Không ai muốn hỗ trợ cho CAD2004 ư??? Khổ cái thân tui quá. Thôi thì .... ráng kiếm tiền để chơi dời mới vậy...... Hề hề hề ,....

[nhoclangbat 392]

Oh, anh Bình còn xài 2004 ah :D, chắc anh Bình tính xài lun bản quyền mới cần để dành xiền nhỉ ^^, cho nhoc hỏi tí nếu mình mua bản quyền thì nhiu xiền nhỉ ^^

[ThuyLinh313 156]

Hề hề hề,

Không ai muốn hỗ trợ cho CAD2004 ư??? Khổ cái thân tui quá. Thôi thì .... ráng kiếm tiền để chơi dời mới vậy...... Hề hề hề ,....

Nếu viết để hỗ trợ cho cad 2004 thì phải viết theo 1 cách khác hoàn toàn khác bạn ạ. Mình chưa thử nên cũng không dám chắc có viết được hay không. Còn lisp trên mình viết dựa vào việc theo dõi sự thay đổi của biến hệ thống TEXTEDITOR. Biến hệ thống này chỉ có trên các bản cad 2009 trở lên thôi.

Bạn cứ thử dùng cad cao hơn đi, nếu ngại giao diện Ripbon thì bạn có thể chuyển về giao diện classic là sẽ thấy môi trường làm việc quen thuộc ngay thôi mà. Mình biết là bạn có khả năng viết lisp hỗ trợ công việc. nhưng dù sao thì dùng cad2004 vẫn rất khổ cực nếu so với các bản cad mới. Đôi khi còn gây phiền hà đến đồng nghiệp nếu họ dùng cad cao hơn, mỗi lần chuyển file cho bạn lại mất công lưu thành cad 2004.

[tien2005 245]

Mình xin phép lấy code của @ThuyLinh313 sửa lại các nội dung sau:

- Bổ sung thêm chuyển chế độ gõ Anh/Việt bằng phím ATL+Z

- Chuyển đúng bảng mã cho các text có font khác nhau (chỉ trong 1 lệnh ED của lisp, xem bài #30)

;; free lisp from cadviet.com
;;; this lisp was downloaded from http://www.cadviet.com/forum/index.php?showtopic=66851
;===========================================================;
;   A U T O   U N I K E Y   C O N T R O L   R O U T I N E   ;
;===========================================================;
;                                        	;
;  Version 1.0 - 14/12/2012              	;
; - Support Auto change table code (Unicode, TCVN, VNI)  ;
; - Support for Text & Mtext objects  	;
;                                        	;
;  Version 2.0 - 15/12/2012              	;
; - Added Auto toggle (On/Off) Vietnamese keys 	;
; - Added support for Dimension objects           	;
; - fixed Check-font-code function    	;
;                                        	;
;===========================================================;
; Cadviet.com - Le Thuy Linh 313 - Tri Tue Viet.jsc   ;
;===========================================================;
(vl-load-com)
;;; Go bo Reactor Auto-Unikey cu truoc khi load
(foreach x (cdar (vlr-reactors :vlr-sysvar-reactor))
(if (= (vlr-data x) "Auto-Unikey") (vlr-remove x)))
;;; Tao Reactor Auto-Unikey
(vlr-sysvar-reactor "Auto-Unikey" '((:vlr-sysvarchanged . callback-Unikey)))
;;; Dinh nghia lai lenh ED de lay ename doi tuong
(defun c:ed (/ textedit font ent)
 (while(setq textedit  (car (entsel "\nSelect object: ")))
(setq ent (cdr (assoc 0 (entget textedit))))
(if (wcmatch ent "*TEXT,DIMENSION")
 	(progn
(if(wcmatch ent "*TEXT")
  (setq font (vla-get-stylename (vlax-ename->vla-object textedit)))
  (setq font (vla-get-textstyle (vlax-ename->vla-object textedit)))
  )
(command "ddedit" textedit "")
)
 	)
)
 (princ)
 )
;;; Ham callback dieu khien bo go tieng viet
(defun callback-Unikey (reactor sysvar / code Crfont)
(if (= (car sysvar) "TEXTEDITOR") (progn(sendkeys "^+")(sendkeys "%{Z}")))
(if (> (getvar "TEXTEDITOR") 0)
 (progn
  (if font (setq Crfont font) (setq Crfont (getvar "textstyle")))
  (setq code (check-font-code Crfont))
  (cond ((= code "TCVN3") (sendkeys "^+{F2}"))
 ((= code "UNICODE") (sendkeys "^+{F1}"))
 ((= code "VNI") (sendkeys "^+{F3}"))))))
;;; Ham kiem tra bang ma cua textstyle (su dung true type font)
;;; style: String - ten cua textstlye kiem tra
(defun Check-Font-Code (style / ts font Bold Italic charSet PitchandFamily)
(setq ts (vlax-ename->vla-object (tblobjname "style" style)))
(vla-GetFont ts 'font 'Bold 'Italic 'charSet 'PitchandFamily)
(if (= font "") (setq font (vla-get-fontfile ts)))
(cond ((wcmatch (setq font (strcase font)) "ARIAL*,TAHOMA*,TIMES*,COURIER NEW,CAMBRIA,CONSOLAS,CALIBRI*") "UNICODE")
((wcmatch font ".VN*") "TCVN3")
((wcmatch font "VNI*") "VNI")))
;;; Ham senkeys
(defun SendKeys (keys / wscript)
(vlax-invoke-method (setq wscript (vlax-create-object "WScript.Shell")) 'sendkeys keys)
(vlax-release-object wscript))

[ThuyLinh313 156]

Haha. Bạn làm mình buồn cười mình quá! Đơn giản thế mà không nghĩ ra, cứ suy nghĩ xa xôi đâu đâu.

Không phải "xin phép" mình khách sáo thế đâu, rất vui vì bạn là người đầu tiên chung tay với mình để hoàn thiện ứng dụng này.

 

Các moderator cho mình hỏi chút: Làm thế nào để mình có thể sửa tiêu đề của topic. Mình muốn chuyển tiền tố tiêu đề từ Yêu cầu -> Đã xong ^^

[tien2005 245]

hồi chiều code lại nhưng vội quá mình chưa kiểm tra lại dòng lệnh (command "ddedit" textedit ""), mình nhớ có 1 biến hệ thống ảnh hưởng đến việc kết thúc lênh bằng dấu "" (biến này autocad đời cao không hiện ra qua việc đánh lệnh setvar). Do đó có khả năng xảy ra lổi nếu autocad của máy nào đã thay đổi giá trị của biến này

Mình lại nhớ ^_^ @Ketxu có nói nếu dùng vl-cmdf thì sẽ không bị lổi kết thúc lệnh bằng dấu "" như trên. @ThuyLinh313 thử thay command bằng vl-cmdf xem. Hiện đang ngồi máy không có autocad nên không thử được

[phamngoctukts 714]

Mình thấy cái này hay hay nên edit chút để dùng được cho cad đời thấp. Do vội nên chưa test kỹ không biết có lỗi gì không.

(vl-load-com)
;;; Dinh nghia lai lenh ED de lay ename doi tuong
(defun c:edt (/ textedit font ent)
(SETQ OLDERR *error*
*error* myerror)
(sendkeys "^+")
(while (setq textedit (car (entsel)))
(setq ent (cdr (assoc 0 (entget textedit))))
(if (wcmatch ent "*TEXT")
(progn
(setq font (vla-get-stylename (vlax-ename->vla-object textedit)))
(call font)
)
)  
(command "ddedit" textedit "")
)
(back)
(SETQ *error* OLDERR)
(princ))
;;; Ham call dieu khien bo go tieng viet
(defun call (font / code Crfont)
(if font (setq Crfont font) (setq Crfont (getvar "textstyle")))
  (setq code (check-font-code Crfont))
  (cond ((= code "TCVN3") (sendkeys "^+{F2}"))
((= code "UNICODE") (sendkeys "^+{F1}"))
((= code "VNI") (sendkeys "^+{F3}"))
)
)
;;; Ham tra lai English
(defun back ()
(sendkeys "^+")
)
;;; Ham kiem tra bang ma cua textstyle (su dung true type font)
;;; style: String - ten cua textstlye kiem tra
(defun Check-Font-Code (style / ts font Bold Italic charSet PitchandFamily)
(setq ts (vlax-ename->vla-object (tblobjname "style" style)))
(vla-GetFont ts 'font 'Bold 'Italic 'charSet 'PitchandFamily)
(if (= font "") (setq font (vla-get-fontfile ts)))
(cond ((wcmatch (setq font (strcase font)) "ARIAL*,TAHOMA*,TIMES*,COURIER NEW,CAMBRIA,CONSOLAS") "UNICODE")
   ((wcmatch font ".VN*") "TCVN3")
   ((wcmatch font "VNI*") "VNI")))
;;; Ham senkeys
(defun SendKeys (keys / wscript)
(vlax-invoke-method (setq wscript (vlax-create-object "WScript.Shell")) 'sendkeys keys)
(vlax-release-object wscript))
;;;Ham bay loi
(defun myerror (s)
(if (= s "Function Cancelled") (sendkeys "^+"))
 (setq *error* OLDERR)
 (princ)
)

PS: Mình nghĩ cái này có thể phát triển thêm dùng cho cả block attribute.

[VoHoan 6]

Mình là người lười, hay quên lại gõ text "mổ cò" nữa nên thấy ý tưởng này cũng hay đấy, lấy về dùng xem sao.

Lisp chạy tốt nhưng có vấn đề này mong TL hày Tien2005 xem lại với:

1. Khi dùng lisp đánh lệnh "ed" của lisp thì dùng tốt nhưng bình thường muốn sửa text mình hay kích đúp chuột thì lisp không còn tự chuyển mã gõ nữa.

2. Nên mặc định unikey ở chế độ tiếng Việt khi dùng lisp dù trước đó unikey đang ở chế độ TV hay E.

[ThuyLinh313 156]

@Vo Hoan: Trong lisp ban đầu của mình (ver2.0) thì kích dupble vẫn được. Lisp do bạn Tien2005 sửa lại thì mới bị mất chức năng này. Để mình kiểm tra lại xem nguyên nhân do đâu.

Lisp này viết bị phụ thuộc hoàn toàn vào các phím tắt của Unikey, Unikey chi cung cấp cho ta 1 cái "công tắc" chuyển đổi on<->off chứ không có nút ON riêng và OFF riêng. Thế nên để làm như bạn muốn là điều không thể. Phải chấp nhận thôi bạn ạ.

;;;---------------------------------------

Đã tìm ra nguyên nhân. Do Tien2005 sửa lại thuật toán gọi hàm senkeys của minh: Từ việc sử dụng hàm callback của reactor liên kết với sự kiện text bị sửa thành hàm thông thường được gọi trong lệnh edt. Phương pháp này không ổn vì:

- Lisp không thực thi nếu sửa text bằng việc kích dup. như Vo Hoan đã nêu

- Không có tác dụng với các lệnh viết text mới như nguyên bản ver2.0 của mình.

Mình có thể sửa được các thiếu sót này trong bài tiếp theo

 

PS: lisp bạn phamngoctu sửa lại dựa trên lisp bài #35 nên cũng sẽ bị tình trạng tương tự.

[tien2005 245]

hic, mình chỉ sửa hàm ED và bổ sung thêm gửi phím ALT+Z trong hàm callback-Unikey, còn gọi nó như thế nào thì mình chịu

Mình mới kiểm tra lại thì khi kích đúp chuột thì lisp không còn tự chuyển mã gõ ở cả ver 2.0 của ThuyLinh313

Lisp do mình sửa lại vẫn hoạt động tốt với các text mới

ThuyLinh313 kiểm tra kỹ lại xem , chẵng nhẽ với mỗi máy lại có bệnh khác nhau, nếu vậy thì phiền phức quá

Khi kích đúp chuột thì bộ gõ vẫn chuyển nhưng bộ mã thì không

 

P/S: Vấn đề nằm ở biến font trong hàm callback-Unikey

 

Nếu dùng lệnh ED thì biến font = T (có được qua lệnh ssget hoặc entsel) => bảng mã lấy theo đối tượng chọn

Nếu đúp kích chuột thì biến font = nil => bảng mã lấy theo (getvar "textstyle")

[ThuyLinh313 156]

Hihi, Chỉ có lisp của bạn PhamNgocTu bị như vậy. do lúc download 2 lisp của Tien2005 và PhamNgocTu trùng tên nên mình nhầm.

Đúng là ver2.0 của mình vẫn không tự động chuyển mã khi kích đúp. Mình đã có hướng khắc phục rồi. Chiều về mình post để các bạn test ^^

[ThuyLinh313 156]

Version 2.1: Tự động bật/Tắt chế độ gõ tiếng việt, tự động chuyển đổi bảng mã của Unikey khi chỉnh sửa hoặc tạo Text, Mtext, Dimension

- Sửa lệnh Ed để nhận diện các text cần sửa tiếp theo. (Cảm ơn bạn Tien2005 đã hỗ trợ thuật toán ^^)

- Update hỗ trợ thêm thao tác kick đúp để chỉnh sửa text.

;===============================================================;
; 	A U T O   U N I K E Y   C O N T R O L   R O U T I N E 	;
;===============================================================;
;                                                       		;
;  Version 1.0 - 14/12/2012                             		;
;  	- Support Auto change table code (Unicode, TCVN, VNI)	;
;  	- Support for Text & Mtext objects               		;
;                                                       		;
;  Version 2.0 - 15/12/2012                             		;
;  	- Added Auto toggle (On/Off) Vietnamese keys     		;
;  	- Added support for Dimension objects                	;
;  	- fixed Check-font-code function                 		;
;                                                       		;
;  Version 2.1 - 22/01/2013                             		;
;  	- Added support for Double click to edit *text   		;
;  	- fixed ED command to select continues (thanks Tien2005) ;
;                                                       		;
;===============================================================;
;  	Cadviet.com - Le Thuy Linh 313 - Tri Tue Viet.jsc    	;
;===============================================================;
(vl-load-com)
;;; Go bo Reactor Auto-Unikey cu truoc khi load
(foreach x (cdar (vlr-reactors :vlr-sysvar-reactor))
(if (= (vlr-data x) "Auto-Unikey") (vlr-remove x)))
(foreach x (cdar (vlr-reactors :vlr-mouse-reactor))
(if (= (vlr-data x) "Double-Click") (vlr-remove x)))
;;; Tao Reactor Auto-Unikey
(vlr-mouse-reactor   "Double-Click" '((:vlr-beginDoubleClick . callback-DoubleClick)))
(vlr-sysvar-reactor "Auto-Unikey" '((:vlr-sysvarchanged . callback-Unikey)))
;;; Dinh nghia lai lenh ED de lay ename doi tuong
(defun c:ed (/ textedit font ent)
(and (or (and (setq textedit (ssget "I" '((0 . "*TEXT,DIMENSION"))))
      		(sssetfirst textedit)
      		(setq textedit (ssname textedit 0)))
     	(setq textedit (car (entsel))))
 	(while textedit
  	(setq ent (cdr (assoc 0 (entget textedit))))
  	(cond ((wcmatch ent "*TEXT")
         	(setq font (vla-get-stylename (vlax-ename->vla-object textedit))))
    		((= ent "DIMENSION")
         	(setq font (vla-get-textstyle (vlax-ename->vla-object textedit)))))
  	(command "ddedit" textedit "")
  	(setq textedit (car (entsel)))))
(princ))
;;; Ham callback dieu khien bo go tieng viet
(defun callback-Unikey (reactor sysvar / code Crfont)
(if (= (car sysvar) "TEXTEDITOR") (sendkeys "^+"))
(if (> (getvar "TEXTEDITOR") 0)
 (progn
  (if font (setq Crfont font) (setq Crfont (getvar "textstyle")))
  (setq code (check-font-code Crfont))
  (cond ((= code "TCVN3") (sendkeys "^+{F2}"))
		((= code "UNICODE") (sendkeys "^+{F1}"))
		((= code "VNI") (sendkeys "^+{F3}")))
  (setq font nil))))
;;; Ham callback lay textstyle khi Double Click vao text
(defun callback-DoubleClick (reactor point / sset obj ss)
(setq sset (vla-get-selectionsets (vla-get-activedocument (vlax-get-acad-object))))
(setq ss (vla-add sset "ThuyLinh313"))
(vla-selectatpoint ss (vlax-3d-point (car point)))
(if (> (vlax-get ss 'Count) 0)
 (progn
  (setq obj (vla-item ss 0))
  (if (or (eq (vlax-get obj 'ObjectName) "AcDbText")
  		(eq (vlax-get obj 'ObjectName) "AcDbMText"))
(setq font (vla-get-stylename obj)))
  (sssetfirst nil (ssadd (vlax-vla-object->ename obj)))))
(vla-delete ss))
;;; Ham kiem tra bang ma cua textstyle (su dung true type font)
;;; style: String - ten cua textstlye kiem tra
(defun Check-Font-Code (style / ts font Bold Italic charSet PitchandFamily)
(setq ts (vlax-ename->vla-object (tblobjname "style" style)))
(vla-GetFont ts 'font 'Bold 'Italic 'charSet 'PitchandFamily)
(if (= font "") (setq font (vla-get-fontfile ts)))
(cond ((wcmatch (setq font (strcase font)) "ARIAL*,TAHOMA*,TIMES*,COURIER NEW,CAMBRIA,CONSOLAS") "UNICODE")
((wcmatch font ".VN*") "TCVN3")
((wcmatch font "VNI*") "VNI")))
;;; Ham senkeys
(defun SendKeys (keys / wscript)
(vlax-invoke-method (setq wscript (vlax-create-object "WScript.Shell")) 'sendkeys keys)
(vlax-release-object wscript))

(Chú ý: cần thiết lập chế độ gõ tiếng anh mặc định khi sử dụng cad; Ứng dụng này tạm thời chỉ hỗ trợ cad 2009 trở lên)

 

Từ ý tưởng của bạn Phamngoctukts thì mình nảy sinh ý định viết ứng dụng này để hỗ trợ với tất cả các loại text trong bản vẽ: attribute, text trong khối block, rtext... Hi vọng sẽ làm được trong các version tiếp theo :D

Chỉnh sửa Tháng 1 29, 2013 theo ThuyLinh313

[avi612 15]

Mình có check thử cái lisp này thì nó hoạt động ko như ý lắm.

Cụ thể là khi load vào và gõ lệnh "ed", chọn 1 text trên bản vẽ thì chỉ thấy nó chuyển Unikey từ gõ TV sang tiếng Anh, cho nên việc bỏ dấu ko thực hiện đc. Mọi người check thử xem sao....

[ThuyLinh313 156]

"Đọc kỹ hướng dẫn sử dụng trước khi dùng" nhé. Bạn cần thiết lập mặc định chế độ gõ tiếng anh khi sử dụng Cad. (thường thì không ai để chế độ gõ tiếng việt nếu vẽ cad cả. gõ lệnh rất khổ)

[duy782006 1592]

Cách của mình dùng lâu nay thấy vẩn ổn ầm ầm.

1.Ko sử dụng bản vẽ của người khác (tạp nham các thứ kể cả text)

2.Dùng 1 bảng mã ổn định trong bản vẽ.

3.Dùng kiểu gỏ vni và mặc định gỏ tiếng Việt trong bộ gỏ.

 

Đây là ý khoe cách làm việc của mình mọi người thấy hay ko cần khen, thấy dở ko cần chê, thấy gai mắt ko cần chửi!

[tien2005 245]

hihi, có 3 text 3 kiểu font thì double click sửa đến text thứ 2 vẫn ok, đến text thứ 3 bị lổi không chuyển bảng mã

CÒn 1 vuệc nữa hơi mất công là khi ban đã chọn đối tượng xong rồi mới đánh lệnh ED thì khi sửa xong text và enter nó lại chọn text vừa rồi, bạn phải enter lần nữa để có thể chọn text kế tiếp

[ThuyLinh313 156]

Duy782006 gõ theo kiểu VNI thì đúng là không cần dùng đến lisp này, vấn đề là đa số người việt gõ kiểu Telex, mình cũng vậy :D

@tien2005. Đúng là phải có nhiều người test mới ra bệnh được ^^

- bệnh thứ nhất: Chính xác thì ngay từ lần chọn text thứ hai (khi double click để sửa text) lisp đã chạy sai rồi. từ lần thứ 2 trở đi nó mặc định là unicode luôn. Sửa bệnh này mình có thể làm được nhưng hơi phức tạp và can thiệp hơi sâu vào hệ thống lệnh của cad, do thao tác double click gọi thẳng đến lệnh gốc ddedit luôn chứ không phải lệnh ed nữa. sự can thiệp này có thể dẫn đến các lỗi mà mình không thể lường trước cho các lệnh khác của cad nên mình sẽ không sửa nữa. bệnh này cũng không quá nghiêm trọng trong quá trình sử dụng.

- bệnh thứ 2: mình đã fix rồi nhé. bạn có thể down lại lisp ở trên.

[ketxu 2994]

ED là lệnh tắt mà ^^

[Thaistreetz 539]

Để viết cho attribute @ThuyLinh cần tìm hiểu thêm về các kiểu đối số của hàm command. Đố làm được đấy!