Nhờ sửa lisp dim polyline

[vanhuyou 25]

Chào mọi người mình tìm được 1 lisp dim polyline nhưng muốn chỉnh lại theo nhu cầu của mình, khi dùng các phân đoạn arc trong polyline sẽ được dim theo 2 điểm đầu và cuối, nhờ mọi người sữa giúp mình để các phân đoạn arc đó dùng dimarc để dim. Cám ơn mọi người.

dpl.dwg

DPL_Automatic Dimension Pline.lsp

[Danh Cong 422]

1 giờ} trướ}c, vanhuyou đã nói:

DPL_Automatic Dimension Pline.lsp

 

+Góp ý : Diễn đàn có tính năng tìm kiếm, bạn có thể dùng nó được mà ?

Không phải vấn đề nào bạn cũng đưa lên diễn đàn, mà bạn hãy tìm kiếm 1 thời gian trước khi đặt ra câu hỏi lên diễn đàn.

 

 

 

[vanhuyou 25]

36 phút trước, Danh Cong đã nói:

 

+Góp ý : Diễn đàn có tính năng tìm kiếm, bạn có thể dùng nó được mà ?

Không phải vấn đề nào bạn cũng đưa lên diễn đàn, mà bạn hãy tìm kiếm 1 thời gian trước khi đặt ra câu hỏi lên diễn đàn.

 

 

 

Cám ơn bạn mình có xem nhưng lisp đó phải pick điểm đặt cho dim và phải làm từng pline 1.

Nhờ mọi người sữa giúp mình là điểm đặt dim tự động ở điểm đầu hoặc điểm cuối củng được, và có thể quét 1 lần nhiều pline.

[huunhantvxdts 195]

3 giờ trước, vanhuyou đã nói:

Cám ơn bạn mình có xem nhưng lisp đó phải pick điểm đặt cho dim và phải làm từng pline 1.

Nhờ mọi người sữa giúp mình là điểm đặt dim tự động ở điểm đầu hoặc điểm cuối củng được, và có thể quét 1 lần nhiều pline.

Mình thấy lisp ở trong bài @Danh Conggợi ý cũng đáp ứng yêu cầu ở trên của bạn rồi. chỉ cần set lại vị trí điểm đặt =0 nữa là ok.

Bạn nên vào bài trên đó yêu cầu thêm. 

 

[gia_bach 1.550]

6 giờ trước, vanhuyou đã nói:

Chào mọi người mình tìm được 1 lisp dim polyline nhưng muốn chỉnh lại theo nhu cầu của mình, khi dùng các phân đoạn arc trong polyline sẽ được dim theo 2 điểm đầu và cuối, nhờ mọi người sữa giúp mình để các phân đoạn arc đó dùng dimarc để dim. Cám ơn mọi người.

dpl.dwg

DPL_Automatic Dimension Pline.lsp

Bạn thử Lisp này.

chú ý chọn Dim_style trước khi chạy lệnh nhé.

(defun c:dimpl(/ doc ep i mp obj oldosn pllst plset sp spc)
  (defun LM:BulgeCenter ( p1 p2 b )
    (polar p1
	   (+ (angle p1 p2) (- (/ pi 2) (* 2 (atan b))))
	   (/ (* (distance p1 p2) (1+ (* b b))) 4 b)    ))
  
  (princ "\n<<< Select LwPolyline for dimensioning >>> ")
  (setq doc (vla-get-activedocument (vlax-get-acad-object))
        spc (vlax-get doc (if (eq (getvar 'CVPORT) 1)
			    'Paperspace
			    'Modelspace	    )	    )  )
  
  (if(setq plSet(ssget '((0 . "LWPOLYLINE"))))
    (progn
      (setq pLlst(vl-remove-if 'listp(mapcar 'cadr(ssnamex plSet)))
	    oldOsn (getvar "OSMODE"))
      (setvar "OSMODE" 0)
      (foreach pl pLlst
	(setq obj (vlax-ename->vla-object pl)
	      i 0)
	(Repeat (fix (vlax-curve-getEndParam obj))
	  (setq sp (vlax-curve-getpointatparam obj i)
		ep (vlax-curve-getpointatparam obj (1+ i))
		mp (vlax-curve-getpointatparam obj (+ i 0.5)))
	  (if (= 0 (vla-GetBulge obj i))
	    (vla-AddDimAligned spc
	      (vlax-3d-point sp) (vlax-3d-point ep) (vlax-3d-point mp))
	    (vla-AddDimArc spc
	      (vlax-3d-point (LM:BulgeCenter sp ep (vla-GetBulge obj i)))
	      (vlax-3d-point sp) (vlax-3d-point ep) (vlax-3d-point mp))
	    );if
	  (setq i (1+ i))
	  ); Repeat
	); end foreach
      (setvar "OSMODE" oldOsn)
      ); end progn
    ); end if
  (princ)
  ); end of defun

 

[vanhuyou 25]

19 phút trước, gia_bach đã nói:

Bạn thử Lisp này.

chú ý chọn Dim_style trước khi chạy lệnh nhé.

• dimpl.lsp
  
• [✎]
   

(defun c:dimpl(/ doc ep i mp obj oldosn pllst plset sp spc)
  (defun LM:BulgeCenter ( p1 p2 b )
    (polar p1
	   (+ (angle p1 p2) (- (/ pi 2) (* 2 (atan b))))
	   (/ (* (distance p1 p2) (1+ (* b b))) 4 b)    ))
  
  (princ "\n<<< Select LwPolyline for dimensioning >>> ")
  (setq doc (vla-get-activedocument (vlax-get-acad-object))
        spc (vlax-get doc (if (eq (getvar 'CVPORT) 1)
			    'Paperspace
			    'Modelspace	    )	    )  )
  
  (if(setq plSet(ssget '((0 . "LWPOLYLINE"))))
    (progn
      (setq pLlst(vl-remove-if 'listp(mapcar 'cadr(ssnamex plSet)))
	    oldOsn (getvar "OSMODE"))
      (setvar "OSMODE" 0)
      (foreach pl pLlst
	(setq obj (vlax-ename->vla-object pl)
	      i 0)
	(Repeat (fix (vlax-curve-getEndParam obj))
	  (setq sp (vlax-curve-getpointatparam obj i)
		ep (vlax-curve-getpointatparam obj (1+ i))
		mp (vlax-curve-getpointatparam obj (+ i 0.5)))
	  (if (= 0 (vla-GetBulge obj i))
	    (vla-AddDimAligned spc
	      (vlax-3d-point sp) (vlax-3d-point ep) (vlax-3d-point mp))
	    (vla-AddDimArc spc
	      (vlax-3d-point (LM:BulgeCenter sp ep (vla-GetBulge obj i)))
	      (vlax-3d-point sp) (vlax-3d-point ep) (vlax-3d-point mp))
	    );if
	  (setq i (1+ i))
	  ); Repeat
	); end foreach
      (setvar "OSMODE" oldOsn)
      ); end progn
    ); end if
  (princ)
  ); end of defun

 

Cám ơn bạn, đúng ý mình rồi